mirror of
https://github.com/open-webui/open-webui.git
synced 2026-09-16 23:43:03 +00:00
ca9ec06c7e
The main and CUDA Docker images get about 21 MB smaller (the nltk package, the punkt_tab data and its zip); slim images, which never downloaded the data, about 6 MB. nltk was in the image for unstructured, which used it to tokenize documents. The Dockerfile download was added for airgapped containers failing on the missing punkt_tab data (#21150; the same request in #16260), the same lookup failed on first use in other setups (#17594, #4642), and the download in start.sh and start_windows.bat came with the Playwright web loader mode and sits in that branch. unstructured 0.22.31, the pinned version, has no nltk references at all and tokenizes with spaCy, nothing else installed requires nltk outside transformers' testing and dev extras, and nothing in the backend imports it, so the pin and both downloads go together. One user-visible consequence: a tool or function that imports nltk inside the container stops working unless it declares nltk in its frontmatter requirements. On an offline instance the package, and any nltk data such as punkt_tab, have to be installed into the image instead. Part of #29721.
58 lines
2.3 KiB
Batchfile
58 lines
2.3 KiB
Batchfile
:: This method is not recommended, and we recommend you use the `start.sh` file with WSL instead.
|
|
@echo off
|
|
SETLOCAL ENABLEDELAYEDEXPANSION
|
|
|
|
:: Get the directory of the current script
|
|
SET "SCRIPT_DIR=%~dp0"
|
|
cd /d "%SCRIPT_DIR%" || exit /b
|
|
|
|
:: Add conditional Playwright browser installation
|
|
IF /I "%WEB_LOADER_ENGINE%" == "playwright" (
|
|
IF "%PLAYWRIGHT_WS_URL%" == "" (
|
|
echo Installing Playwright browsers...
|
|
playwright install chromium
|
|
playwright install-deps chromium
|
|
)
|
|
)
|
|
|
|
SET "KEY_FILE=.webui_secret_key"
|
|
IF NOT "%WEBUI_SECRET_KEY_FILE%" == "" (
|
|
SET "KEY_FILE=%WEBUI_SECRET_KEY_FILE%"
|
|
)
|
|
|
|
IF "%PORT%"=="" SET PORT=8080
|
|
IF "%HOST%"=="" SET HOST=0.0.0.0
|
|
IF "%FORWARDED_ALLOW_IPS%"=="" SET "FORWARDED_ALLOW_IPS='*'"
|
|
SET "WEBUI_SECRET_KEY=%WEBUI_SECRET_KEY%"
|
|
SET "WEBUI_JWT_SECRET_KEY=%WEBUI_JWT_SECRET_KEY%"
|
|
IF "%WEBUI_SECRET_KEY_LENGTH%" == "" (
|
|
SET "WEBUI_SECRET_KEY_LENGTH=24"
|
|
)
|
|
|
|
:: Check if WEBUI_SECRET_KEY and WEBUI_JWT_SECRET_KEY are not set
|
|
IF "%WEBUI_SECRET_KEY% %WEBUI_JWT_SECRET_KEY%" == " " (
|
|
echo Loading WEBUI_SECRET_KEY from file, not provided as an environment variable.
|
|
|
|
IF NOT EXIST "!KEY_FILE!" (
|
|
echo Generating WEBUI_SECRET_KEY
|
|
:: Generate a random value to use as a WEBUI_SECRET_KEY in case the user didn't provide one
|
|
SET "CHARSET=0123456789abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ"
|
|
SET "WEBUI_SECRET_KEY="
|
|
FOR /L %%i IN (1,1,!WEBUI_SECRET_KEY_LENGTH!) DO (
|
|
SET /A "INDEX=!RANDOM! %% 62"
|
|
FOR %%j IN (!INDEX!) DO SET "WEBUI_SECRET_KEY=!WEBUI_SECRET_KEY!!CHARSET:~%%j,1!"
|
|
)
|
|
<nul SET /p="!WEBUI_SECRET_KEY!">"!KEY_FILE!"
|
|
echo WEBUI_SECRET_KEY generated
|
|
)
|
|
|
|
echo Loading WEBUI_SECRET_KEY from !KEY_FILE!
|
|
SET /p WEBUI_SECRET_KEY=<"!KEY_FILE!"
|
|
)
|
|
|
|
:: Execute uvicorn
|
|
SET "WEBUI_SECRET_KEY=%WEBUI_SECRET_KEY%"
|
|
IF "%UVICORN_WORKERS%"=="" SET UVICORN_WORKERS=1
|
|
if "%UVICORN_WS_PER_MESSAGE_DEFLATE%" == "" set "UVICORN_WS_PER_MESSAGE_DEFLATE=true"
|
|
uvicorn open_webui.main:app --host "%HOST%" --port "%PORT%" --forwarded-allow-ips %FORWARDED_ALLOW_IPS% --workers %UVICORN_WORKERS% --ws auto --ws-per-message-deflate %UVICORN_WS_PER_MESSAGE_DEFLATE%
|
|
:: For ssl user uvicorn open_webui.main:app --host "%HOST%" --port "%PORT%" --forwarded-allow-ips '*' --ssl-keyfile "key.pem" --ssl-certfile "cert.pem" --ws auto
|